pulisco la memoria

kill(all);

definisco (per assegnazione) il momento flettente sui tratti AB e BC

MfAB : R*s ;
MfBC : R*(b+s)-P*s ;

UAB : integrate( MfAB^2/2/E/J ,  s , 0 , b );

UBC : integrate ( MfBC^2/2/E/J , s, 0, a );

U : UAB + UBC ;

U : expand( U );

U;

calcolo frecce in A e B, positive se verso il basso; utilizzo il secondo teorema di Castigliano

fA : - diff( U , R );

fB : + diff( U , P );

essendo la risposta della struttura assunta lineare, dovrebbe risultare che
fA = alpha * P + beta * R; ricaviamo tali coefficienti

alpha : factor( coeff(fA,P) );
beta  : factor( coeff(fA,R) );

verifichiamo che le espressioni di fA tal quale e fA espresso come combinazione lineare siano equivalenti

ratsimp( fA - (alpha*P + beta*R) );

impongo nullo fA, ricavando il valore della reazione vincolare R

defR : linsolve( [fA=0] , [R] );
R : ev( R , defR );

linsolve( [fA=0] , [R] ) , globalsolve=true;

R;

ratsimp( ev( fA ) );

fB : factor( ev( fB ) );

fB;

provo a rappresentare i risultati ottenuti in precedenza in funzione della lunghezza dimensionale l=a+b e del rapporto adimensionale eta=a/l, 0<=eta<=1

a =    eta *l
b = (1-eta)*l

procedo con le sostituzioni

[fB,R] $
ratsubst(    eta *l , a , % ) $
ratsubst( (1-eta)*l , b , % ) $
factor( % );
[fB,R] : % $

[fB, R] , eta=1/2;

cerco il valore di eta per il quale l'abbassamento del punto di applicazione del carico e' massimo

eqns : [ expand( diff(fB , eta) ) = 0 ];

unks : [ eta ];

sols:solve( eqns , unks  );

sols[1] , numer;

ev(fB,sols[1]),numer;